CMakeLists.txt

#   ____  _             _       
#  |  _ \| |_   _  __ _(_)_ __  
#  | |_) | | | | |/ _` | | '_ \ 
#  |  __/| | |_| | (_| | | | | |
#  |_|   |_|\__,_|\__, |_|_| |_|
#                 |___/         
# A Template for ScriptPlugin, a Filter Plugin
# Generated by the command: plugin -t filter -d script_plugin script
# Hostname: Fram-IV.local
# Current working directory: /Users/p4010/Develop/MADS_plugins
# Creation date: 2024-08-23T12:09:57.009+0200
# NOTICE: MADS Version 1.0.3
cmake_minimum_required(VERSION 3.28)
set(CMAKE_POLICY_VERSION_MINIMUM 3.5)
project(script VERSION 1.0.3 LANGUAGES CXX)
if(CMAKE_BUILD_TYPE STREQUAL "")
  set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build." FORCE)
endif()
if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  execute_process(
    COMMAND mads -p
    OUTPUT_VARIABLE MADS_PREFIX
    OUTPUT_STRIP_TRAILING_WHITESPACE
    ERROR_QUIET
  )
  if(MADS_PREFIX)
    set(CMAKE_INSTALL_PREFIX "${MADS_PREFIX}" CACHE PATH "Install path prefix, prepended onto install directories." FORCE)
  endif()
endif()
message(STATUS "CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
message(STATUS "CMAKE_INSTALL_PREFIX: ${CMAKE_INSTALL_PREFIX}") 

# PROJECT SETTINGS #############################################################
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(SRC_DIR ${CMAKE_CURRENT_LIST_DIR}/src)

if(UNIX AND NOT APPLE)
  set(LINUX TRUE)
  add_compile_options(-fPIC)
endif()

# DEPENDENCIES #################################################################
include(FetchContent)
# pugg is for the plugin system
FetchContent_Declare(pugg 
  GIT_REPOSITORY https://github.com/pbosetti/pugg.git
  GIT_TAG        1.1.0
  GIT_SHALLOW    TRUE
  EXCLUDE_FROM_ALL
)

set(BUILD_TESTING OFF CACHE INTERNAL "")
set(JSON_BuildTests OFF CACHE INTERNAL "")
FetchContent_Declare(json
  URL https://github.com/nlohmann/json/releases/download/v3.11.3/json.tar.xz
  DOWNLOAD_EXTRACT_TIMESTAMP TRUE
)

FetchContent_MakeAvailable(pugg json)

FetchContent_Populate(plugin 
  GIT_REPOSITORY https://github.com/pbosetti/mads_plugin.git
  GIT_TAG        v2.3-P7
  GIT_SHALLOW    TRUE
)

FetchContent_Populate(sol2
  GIT_REPOSITORY https://github.com/ThePhD/sol2.git
  GIT_TAG        v3.5.0
  GIT_SHALLOW    TRUE
)




include_directories(${plugin_SOURCE_DIR}/src)
add_definitions(-DINSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}")

if(NOT WIN32)
  add_compile_options(-Wno-unknown-warning-option)
endif()

set(LUA_URL https://www.lua.org/ftp/lua-5.4.3.tar.gz)
include(ExternalProject)
if (WIN32)
  set(WIN_FOLDER ${CMAKE_CURRENT_LIST_DIR}/windows)
  ExternalProject_Add(lua
    PREFIX ${WIN_FOLDER}/lua
    DOWNLOAD_DIR ${WIN_FOLDER}/lua
    SOURCE_DIR ${WIN_FOLDER}/lua
    BINARY_DIR ${WIN_FOLDER}/lua-build
    STAMP_DIR ${WIN_FOLDER}/stamp
    DOWNLOAD_EXTRACT_TIMESTAMP TRUE
    URL ${LUA_URL}
    PATCH_COMMAND ${CMAKE_COMMAND} -E copy ${WIN_FOLDER}/CMakeLists.txt ${WIN_FOLDER}/lua/CMakeLists.txt
  )
  include_directories(
    ${WIN_FOLDER}/lua/src
  )
  link_directories(${WIN_FOLDER}/lib)
else()
  ExternalProject_Add(lua
    URL ${LUA_URL}
    CONFIGURE_COMMAND ""
    BUILD_COMMAND make $<IF:$<BOOL:${LINUX}>,linux-readline,guess> MYCFLAGS=-fPIC
    BUILD_IN_SOURCE TRUE
    INSTALL_COMMAND make install INSTALL_TOP=${CMAKE_BINARY_DIR}/lua
    DOWNLOAD_EXTRACT_TIMESTAMP TRUE
  )
  include_directories(
    ${CMAKE_BINARY_DIR}/lua/include
  )
  link_directories(${CMAKE_BINARY_DIR}/lua/lib)
endif()

# MACROS #######################################################################
# Call: add_plugin(name [SRCS src1 src2 ...] [LIBS lib1 lib2 ...])
#       the source file ${SRC_DIR}/plugin/<name>.cpp is implicitly added
macro(add_plugin name)
  # on MacOS only, plugins can be compiled as executables
  set(multiValueArgs LIBS SRCS)
  cmake_parse_arguments(plugin "" "" "${multiValueArgs}" ${ARGN})
  if (APPLE)
    add_executable(${name} ${SRC_DIR}/${name}.cpp ${plugin_SRCS})
    set_target_properties(${name} PROPERTIES ENABLE_EXPORTS TRUE)
    set(${name}_EXEC ${name}.plugin)
  else()
    add_library(${name} SHARED ${SRC_DIR}/${name}.cpp ${plugin_SRCS})
    add_executable(${name}_main ${SRC_DIR}/${name}.cpp ${plugin_SRCS})
    target_link_libraries(${name}_main PRIVATE pugg ${plugin_LIBS})
    set_target_properties(${name}_main PROPERTIES OUTPUT_NAME ${name})
    set(${name}_EXEC ${name})
    list(APPEND TARGET_LIST ${name}_main)
  endif()
  target_link_libraries(${name} PRIVATE pugg ${plugin_LIBS})
  set_target_properties(${name} PROPERTIES PREFIX "")
  set_target_properties(${name} PROPERTIES SUFFIX ".plugin")
  target_compile_definitions(${name} PRIVATE PLUGIN_NAME="${name}")
  list(APPEND TARGET_LIST ${name})
endmacro()


# BUILD SETTINGS ###############################################################
if (APPLE)
  set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
  include_directories(/opt/homebrew/include)
  link_directories(/opt/homebrew/lib)
else()
  set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib;/usr/local/lib")
endif()
include_directories(
  ${json_SOURCE_DIR}/include 
  ${sol2_SOURCE_DIR}/include
)

set(LUA_LIB $<IF:$<BOOL:${WIN32}>,lua.lib,liblua.a>)

# These plugins are always build and use for testing
add_plugin(lua_source LIBS ${LUA_LIB})
add_dependencies(lua_source lua)

add_plugin(lua_filter LIBS ${LUA_LIB})
add_dependencies(lua_filter lua)

add_plugin(lua_sink LIBS ${LUA_LIB})
add_dependencies(lua_sink lua)


# INSTALL ######################################################################
if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  set_property(CACHE CMAKE_INSTALL_PREFIX PROPERTY VALUE ${USR_DIR})
endif()
if(APPLE)
  install(TARGETS ${TARGET_LIST}
    LIBRARY DESTINATION lib
    RUNTIME DESTINATION lib
    ARCHIVE DESTINATION lib
  )
else()
  install(TARGETS ${TARGET_LIST}
    LIBRARY DESTINATION lib
    RUNTIME DESTINATION bin
    ARCHIVE DESTINATION lib
  )
endif()
install(DIRECTORY ${CMAKE_CURRENT_LIST_DIR}/lua DESTINATION .)