Advanced examples

[mfxpyro1]

Hi, thanks for this Library, would it be possible to create some more advanced examples showing how to send multiple byte/different types of data? For example I want to send the data contained in this this and obviously receive it at the other end :-

struct dataStruct{unsigned long Packet; int Accel; int Brake; int Steer; byte SwA; byte SwB; byte SwC; byte SwD;}myData;

I've tried :-

        icsc.send('B',(uint8_t)myData, sizeof(myData));

But get the error :-

"invalid cast from type 'dataStruct' to type 'uint8_t {aka unsigned char}'"

and :-

        icsc.send('B',myData, sizeof(myData));

But get the error :-

"no matching function for call to 'ICSC::send(char, dataStruct&, unsigned int)'"

Structs are fairly new to me so wondering how to handle this? And I haven't even started looking at what to do at the receiving end yet.

[majenkotech]

You are almost there. You just need to take the pointer of the structure:

icsc.send('B',(uint8_t*)&myData, sizeof(myData));

[mfxpyro1]

Thanks tried that but still getting an error
"no matching function for call to 'send(char, uint8_t*, unsigned int)'"

Here's the full test code (sorry should have posted it before)

ICSC icsc(Serial, 'A');

//comment out the line above and uncomment the line below to use this with ChainDuinos
//ICSC icsc(Serial, 'A' ,2); // last argument specifies DE pin on ChainDuino

struct dataStruct{unsigned long Packet; int Accel; int Brake; int Steer; byte SwA; byte SwB; byte SwC; byte SwD;}myData;


void setup()
{
  // Fill struct with test data
  myData.Packet=1;
  myData.Accel=2;
  myData.Brake=3;
  myData.Steer=4;
  myData.SwA=5;
  myData.SwB=6;
  myData.SwC=7;
  myData.SwD=8;
  
    Serial.begin(115200);
    icsc.begin();

}

void loop()
{
   icsc.send('B',(uint8_t*)&myData, sizeof(myData)); 
}```

[majenkotech]

Ah, sorry, got the parameters the wrong way around. I should have spotted that. Also should be char* not uint8_t*.

icsc.send('B', sizeof(myData), (char*)&myData);

[mfxpyro1]

Thanks for you very quick responses. What's the purpose of the (char*) ? I'm sending numerical bytes (and int's) not text? Is this going to be a problem at the receiving end ?

[mfxpyro1]

As an example of what I'm trying to do the equivalent of, in the nrf24l01 library I'm using I can do :-

struct dataStruct{unsigned long Packet; int Accel; int Brake; int Steer; byte SwA; byte SwB; byte SwC; byte SwD;}myData;
'''''''
radio.write( &myData, sizeof(myData) )

and at the revive end simply do:-

struct dataStruct{unsigned long Packet; int Accel; int Brake; int Steer; byte SwA; byte SwB; byte SwC; byte SwD;}myData;
......
while (radio.available())
{
radio.read( &myData, sizeof(myData) ); // Read information from the NRF24L01
}

And the receive end struct is populated with the same data as the sending end.

[majenkotech]

char * is just a pointer to some 8-bit data. The term "char" is a bit of a misnomer. It's just 8-bit. It may, or may not, be signed, but that's not something we care about, only that it's 8-bit. If I were writing the library today I'd use uint8_t * and swap the order of the pointer and the size, so it was more "standard".

[mfxpyro1]

Thanks, still a bit stuck as to what I do at the other end to populate the matching struct with the received data. If I get something working can it be included as an example for others?

[majenkotech]

You get handed an 8-bit buffer with the data in. All you need to do is cast that to a pointer to your structure.

struct dataStruct {
    unsigned long Packet; 
    int Accel; 
    int Brake; 
    int Steer; 
    byte SwA; 
    byte SwB; 
    byte SwC; 
    byte SwD;
};

void receivedB(unsigned char src, char command, unsigned char len, char *data) {
    struct dataStruct *myData = (struct dataStruct *)data;
    Serial.println(myData->Steer);
}

...

icsc.registerCommand('B', &receivedB);

[mfxpyro1]

Thanks this is what I have so far :-

Send end

ICSC icsc(Serial, 'A');

struct dataStruct{unsigned long Packet; int Accel; int Brake; int Steer; byte SwA; byte SwB; byte SwC; byte SwD;}myData;

void setup()
{
  myData.Packet=400000;
  myData.Accel=2;
  myData.Brake=3;
  myData.Steer=4;
  myData.SwA=5;
  myData.SwB=6;
  myData.SwC=7;
  myData.SwD=8;
  
  Serial.begin(115200);
  icsc.begin();

}

void loop()
{
icsc.send('B', sizeof(myData), (char*)&myData);
delay(500);
}

Receive end :-

#include <ICSC.h>

ICSC icsc(Serial1, 'B');  //Use port 1 on a Mega

struct dataStruct {
    unsigned long Packet; 
    int Accel; 
    int Brake; 
    int Steer; 
    byte SwA; 
    byte SwB; 
    byte SwC; 
    byte SwD;
};

void setup()
{
    Serial.begin(115200);
    Serial1.begin(115200);
    Serial.println("hello");
    icsc.begin();
    icsc.registerCommand('B', &receivedB);
}

void loop()
{
    icsc.process();
}

void receivedB(unsigned char src, char command, unsigned char len, char *data) 
{
    struct dataStruct *myData = (struct dataStruct *)data;
    Serial.print("Recieved ");
    Serial.print(myData->Packet);
    Serial.print(" , ");
    Serial.print(myData->Accel);
    Serial.print(" , ");
    Serial.print(myData->Brake);
    Serial.print(" , ");    
    Serial.print(myData->Steer);
    Serial.print(" , ");    
    Serial.print(myData->SwA);
    Serial.print(" , ");    
    Serial.print(myData->SwB);
    Serial.print(" , ");    
    Serial.print(myData->SwC);
    Serial.print(" , ");    
    Serial.println(myData->SwD);
}

I'm using a Mega on the receive end so am using port 1 on that for ICSC comms and port 0 for the terminal comms but I'm getting nothing on the terminal. The sender is a Nano.

[majenkotech]

One slight change. It's been a long time since I used this library.

icsc.send('B', sizeof(myData), (char*)&myData);

should be:

icsc.send('B', 'B', sizeof(myData), (char*)&myData);

The second 'B' corresponds to the 'B' in the registerCommand() in the receiver.

[mfxpyro1]

YAY! That works, hopefully this will be useful to others.

Thanks again. Do you have a way I can Donate?

[majenkotech]

There's a donation link on UECIDE.org ;)